asp cookies

cookie 常用于識別用戶。

嘗試一下 - 實例

welcome cookie
本例演示如何創建 welcome cookie。

cookie 是什么？

cookie 常用用于識別用戶。cookie 是一種服務器留在用戶計算機上的小文件。每當同一臺計算機通過瀏覽器請求頁面時，這臺計算機將會發送 cookie。通過 asp，您能夠創建并取回 cookie 的值。

如何創建 cookie？

"response.cookies" 命令用于創建 cookie。

注釋：response.cookies 命令必須出現在 <html> 標簽之前。

在下面的實例中，我們將創建一個名為 "firstname" 的 cookie，并將其賦值為 "alex"：

<%
response.cookies("firstname")="alex"
%>

向 cookie 分配屬性也是可以的，比如設置 cookie 的失效時間：

<%
response.cookies("firstname")="alex"
response.cookies("firstname").expires=#may 10,2012#
%>

如何取回 cookie 的值？

"request.cookies" 命令用于取回 cookie 的值。

在下面的實例中，我們取回了名為 "firstname" 的 cookie 的值，并把值顯示到了頁面上：

<%
fname=request.cookies("firstname")
response.write("firstname=" & fname)
%>

輸出： firstname=alex

帶有鍵的 cookie

如果一個 cookie 包含多個值的集合，我們就可以說 cookie 帶有鍵（keys）。

在下面的實例中，我們將創建一個名為 "user" 的 cookie 集合。"user" cookie 帶有包含用戶信息的鍵：

<%
response.cookies("user")("firstname")="john"
response.cookies("user")("lastname")="smith"
response.cookies("user")("country")="norway"
response.cookies("user")("age")="25"
%>

讀取所有的 cookie

請閱讀下面的代碼：

<%
response.cookies("firstname")="alex"
response.cookies("user")("firstname")="john"
response.cookies("user")("lastname")="smith"
response.cookies("user")("country")="norway"
response.cookies("user")("age")="25"
%>

假設您的服務器將上面所有的 cookie 傳給了某個用戶。

現在，我們需要讀取這些傳給某個用戶的所有的 cookie。下面的實例向您演示了如何做到這一點（請注意，下面的代碼通過 haskeys 屬性檢查 cookie 是否帶有鍵）：

<!doctype html>
<html>
<body>

<%
dim x,y
for each x in request.cookies
response.write("<p>")
if request.cookies(x).haskeys then
for each y in request.cookies(x)
response.write(x & ":" & y & "=" & request.cookies(x)(y))
response.write("<br>")
next
else
response.write(x & "=" & request.cookies(x) & "<br>")
end if
response.write "</p>"
next
%>

</body>
</html>

輸出：

firstname=alex

user:firstname=john
user:lastname=smith
user:country=norway
user:age=25

如果瀏覽器不支持 cookie 該怎么辦？

如果您的應用程序需要與不支持 cookie 的瀏覽器打交道，那么您不得不使用其他的辦法在您的應用程序中的頁面之間傳遞信息。這里有兩種辦法：

1. 向 url 添加參數

您可以向 url 添加參數：

<a href="welcome.asp?fname=john&lname=smith">go to welcome page</a>

然后在 "welcome.asp" 文件中取回這些值，如下所示：

<%
fname=request.querystring("fname")
lname=request.querystring("lname")
response.write("<p>hello " & fname & " " & lname & "!</p>")
response.write("<p>welcome to my web site!</p>")
%>

2. 使用表單

您可以使用表單。當用戶點擊 submit 按鈕時，表單會把用戶輸入傳給 "welcome.asp" ：

<form method="post" action="welcome.asp">
first name: <input type="text" name="fname" value="">
last name: <input type="text" name="lname" value="">
<input type="submit" value="submit">
</form>